; This file is for utilities that are in common to all the timing board
;   programs, located starting at P:$200 in external SRAM


;  ****************  PROGRAM CODE IN SRAM PROGRAM SPACE    *******************
; Put all the following code in SRAM, starting at P:$200.
	IF	@SCP("DOWNLOAD","HOST")
	ORG	P:$200,P:$200	; Download address
	ELSE
	ORG	P:$200,P:APL_NUM*N_W_APL+APL_LEN ; EEPROM address
	ENDIF

; Select which readouts to process
;   'SOS'  Amplifier_name  
;	Amplifier_name = '__A', '__B', '__C', '__D', '_AB', '_CD', or 'ALL'

SEL_OS	MOVE	X:(R4)+,X0		; Get amplifier(s) name
	MOVE	X0,Y:<OS
	JSR	<SELECT_OUTPUT_SOURCE
	JMP	<FINISH1

; This is a host command for setting MPP mode or not: 'MPP' then 0 or 1
SEL_MPP	MOVE	Y:<OS,X0		; Needed to execute SELECT_OUTPUT_SOURCE
	MOVE	X:(R4)+,A
	JSET	#0,A,YES_MPP

NOT_MPP	BCLR	#MPP,X:STATUS		; Not MPP mode
	JSR	<SELECT_OUTPUT_SOURCE	; Update parallel waveform address
	JSR	<SER_ANA
	MOVEP	#((CLK2<<8)+(16<<14)+@CVI((P3_HI+10.0)/20.0*4095)),X:SSITX
	JSR	<PAL_DLY
	JSR	<SER_UTL		; Return SSI to utility board 
	MOVE	#(CLK2+S_DELAY+RG0+RG1+RG2+RG3+P1L+P1U+P2L+P2U),X0
	MOVE	X0,Y:RGH_1
	MOVE	X0,Y:RGH_2
	MOVE	X0,Y:RGH_3
	MOVE	X0,Y:RGH_4
	MOVE	X0,Y:RGH_5
	MOVE	X0,Y:RGH_6
	MOVE	X0,Y:RGH_7
	MOVE	X0,Y:RGH_8
	MOVE	X0,Y:RGH_9
	MOVE	X0,Y:RGH_10
	MOVE	#(CLK2+S_DELAY+P1L+P1U+P2L+P2U+S2L+S2U),X0
	MOVE	X0,Y:RGL_1
	MOVE	X0,Y:RGL_2
	MOVE	X0,Y:RGL_3
	MOVE	X0,Y:RGL_4
	MOVE	X0,Y:RGL_5
	MOVE	X0,Y:RGL_6
	MOVE	X0,Y:RGL_7
	MOVE	X0,Y:RGL_8
	MOVE	X0,Y:RGL_9
	MOVE	X0,Y:RGL_10
	JMP	<FINISH

YES_MPP	BSET	#MPP,X:STATUS		; MPP mode
	JSR	<SELECT_OUTPUT_SOURCE	; Update parallel waveform address
	JSR	<SER_ANA
	MOVEP	#((CLK2<<8)+(16<<14)+$FFF),X:SSITX	; P3 High +2.5V for MPP
	JSR	<PAL_DLY
	JSR	<SER_UTL		; Return SSI to utility board 
	MOVE	#(CLK2+S_DELAY+RG0+RG1+RG2+RG3),X0
	MOVE	X0,Y:RGH_1
	MOVE	X0,Y:RGH_2
	MOVE	X0,Y:RGH_3
	MOVE	X0,Y:RGH_4
	MOVE	X0,Y:RGH_5
	MOVE	X0,Y:RGH_6
	MOVE	X0,Y:RGH_7
	MOVE	X0,Y:RGH_8
	MOVE	X0,Y:RGH_9
	MOVE	X0,Y:RGH_10
	MOVE	#(CLK2+S_DELAY+S2L+S2U),X0
	MOVE	X0,Y:RGL_1
	MOVE	X0,Y:RGL_2
	MOVE	X0,Y:RGL_3
	MOVE	X0,Y:RGL_4
	MOVE	X0,Y:RGL_5
	MOVE	X0,Y:RGL_6
	MOVE	X0,Y:RGL_7
	MOVE	X0,Y:RGL_8
	MOVE	X0,Y:RGL_9
	MOVE	X0,Y:RGL_10
	JMP	<FINISH

; A massive subroutine for setting all the addresses depending on the
;   output source(s) selection. 
SELECT_OUTPUT_SOURCE

; Set all the waveform addresses depending on which readout mode
	MOVE	#'__A',A		; Amplifier A = readout #3
	CMP	X0,A
	JNE	<CMP_B
	MOVE	#SERIAL_SKIP_A,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_READ_A,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F063,A
	MOVE	A,Y:SXMIT_A
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_A,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_UPPER,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_A
	MOVE	#PARALLEL_UPPER_MPP,A
	MOVE	A,Y:PARALLEL
MPP_A	BCLR	#SPLIT_S,X:STATUS
	BCLR	#SPLIT_P,X:STATUS
	JMP	<CMP_END

CMP_B	MOVE	#'__B',A		; Amplifier B = readout #2
	CMP	X0,A
	JNE	<CMP_C
	MOVE	#SERIAL_SKIP_B,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_READ_B,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F042,A
	MOVE	A,Y:SXMIT_B
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_B,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_UPPER,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_B
	MOVE	#PARALLEL_UPPER_MPP,A
	MOVE	A,Y:PARALLEL
MPP_B	BCLR	#SPLIT_S,X:STATUS
	BCLR	#SPLIT_P,X:STATUS
	JMP	<CMP_END

CMP_C	MOVE	#'__C',A		; Amplifier C = readout #0
	CMP	X0,A
	JNE	<CMP_D
	MOVE	#SERIAL_SKIP_B,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_READ_B,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F000,A
	MOVE	A,Y:SXMIT_B
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_B,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_LOWER,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_C
	MOVE	#PARALLEL_LOWER_MPP,A
	MOVE	A,Y:PARALLEL
MPP_C	BCLR	#SPLIT_S,X:STATUS
	BCLR	#SPLIT_P,X:STATUS
	JMP	<CMP_END

CMP_D	MOVE	#'__D',A		; Amplifier D = readout #1
	CMP	X0,A
	JNE	<CMP_AB
	MOVE	#SERIAL_SKIP_A,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_READ_A,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F021,A
	MOVE	A,Y:SXMIT_A
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_A,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_LOWER,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_D
	MOVE	#PARALLEL_LOWER_MPP,A
	MOVE	A,Y:PARALLEL
MPP_D	BCLR	#SPLIT_S,X:STATUS
	BCLR	#SPLIT_P,X:STATUS
	JMP	<CMP_END

CMP_AB	MOVE	#'_AB',A		; Amplifiers A and B = readouts #2,3
	CMP	X0,A
	JNE	<CMP_CD
	MOVE	#SERIAL_SKIP_SPLIT,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_SPLIT,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F062,A
	MOVE	A,Y:SXMIT_AB
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_SPLIT,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_UPPER,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_AB
	MOVE	#PARALLEL_UPPER_MPP,A
	MOVE	A,Y:PARALLEL
MPP_AB	BSET	#SPLIT_S,X:STATUS
	BCLR	#SPLIT_P,X:STATUS
	JMP	<CMP_END

CMP_CD	MOVE	#'_CD',A		; Amplifiers C and D = readouts #0,1
	CMP	X0,A
	JNE	<CMP_ALL
	MOVE	#SERIAL_SKIP_SPLIT,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_SPLIT,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F020,A
	MOVE	A,Y:SXMIT_AB
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_SPLIT,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_LOWER,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_CD
	MOVE	#PARALLEL_LOWER_MPP,A
	MOVE	A,Y:PARALLEL
MPP_CD	BSET	#SPLIT_S,X:STATUS
	BCLR	#SPLIT_P,X:STATUS
	JMP	<CMP_END

CMP_ALL	MOVE	#'ALL',A		; All amplifiers = readouts #0 to 3
	CMP	X0,A
	JNE	<CMP_ERROR
	MOVE	#SERIAL_SKIP_SPLIT,A
	MOVE	A,Y:SERIAL_SKIP
	MOVE	#SERIAL_SPLIT,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#$00F060,A
	MOVE	A,Y:SXMIT_AB
	MOVE	A,Y:SXMIT_VIDEO_PROCESS
	MOVE	#SERIAL_CLOCK_SPLIT,A
	MOVE	A,Y:SERIAL_CLOCK
	MOVE	#PARALLEL_SPLIT,A
	MOVE	A,Y:PARALLEL
	JCLR	#MPP,X:STATUS,MPP_ALL
	MOVE	#PARALLEL_SPLIT_MPP,A
	MOVE	A,Y:PARALLEL
MPP_ALL	BSET	#SPLIT_S,X:STATUS
	BSET	#SPLIT_P,X:STATUS
CMP_END	MOVE	#'DON',X0	
	RTS

CMP_ERROR
	MOVE	#'ERR',X0
	RTS