; This file is for utilities that are in common to all the timing board
;   programs, located starting at P:$200 in external SRAM


;  ****************  PROGRAM CODE IN SRAM PROGRAM SPACE    *******************
; Put all the following code in SRAM, starting at P:$200.
	IF	@SCP("DOWNLOAD","HOST")
	ORG	P:$200,P:$200	; Download address
	ELSE
	ORG	P:$200,P:APL_NUM*N_W_APL+APL_LEN ; EEPROM address
	ENDIF

; Fast clear of CCD, executed as a command
CLEAR	JSR	<CLR_CCD
	JMP     <FINISH

; Fast clear image before each exposure, executed as a subroutine
CLR_CCD	DO      Y:<NPCLR,LPCLR		; Loop over number of lines in image
	MOVE    #IS_PARALLEL,R0		; Address of parallel transfer waveform
	JSR     <CLOCK  		; Go clock out the CCD charge
	NOP				; Do loop restriction
LPCLR
	MOVE	#TST_RCV,X0		; Wait for commands during exposure
	MOVE	X0,X:<IDL_ADR		;  instead of idling
	RTS

; Select which readouts to process
;   'SOS'  Amplifier_name  
;	Amplifier_name = '__L', '__R', '_LR'

SEL_OS	MOVE	X:(R4)+,X0		; Get amplifier(s) name
	JSR	<SELECT_OUTPUT_SOURCE
	JMP	<FINISH1

; A massive subroutine for setting all the addresses depending on the
;   output source(s) selection and binning parameter. 
SELECT_OUTPUT_SOURCE

; Set all the waveform addresses depending on which readout mode
	MOVE	#'__L',A		; LEFT Amplifier = readout #0
	CMP	X0,A
	JNE	<CMP_R
	MOVE	#SERIAL_READ_LEFT,A
	MOVE	A,Y:SERIAL_READ
	MOVE	#SERIAL_SKIP_LEFT,A
	MOVE	A,Y:SERIAL_SKIP
	BCLR	#SPLIT_S,X:STATUS
	JMP	<CMP_END

CMP_R	MOVE	#'__R',A		; RIGHT Amplifier = readout #1
	CMP	X0,A
	JNE	<CMP_LR
;	MOVE	#SERIAL_READ_RIGHT,A
;	MOVE	A,Y:SERIAL_READ
;	MOVE	#SERIAL_SKIP_RIGHT,A
;	MOVE	A,Y:SERIAL_SKIP
	BCLR	#SPLIT_S,X:STATUS
	JMP	<CMP_END

CMP_LR	MOVE	#'_LR',A		; LEFT and RIGHT = readouts #0 and #1
	CMP	X0,A
	JNE	<CMP_ERROR
;	MOVE	#SERIAL_READ_SPLIT,A
;	MOVE	A,Y:SERIAL_READ
;	MOVE	#SERIAL_SKIP_SPLIT,A
;	MOVE	A,Y:SERIAL_SKIP
	BSET	#SPLIT_S,X:STATUS
CMP_END	MOVE	#'DON',X0	
	RTS
CMP_ERROR
	MOVE	#'ERR',X0
	RTS

; AIMO NOT yet implemented for EEV57 - just dummy calls

; This is a host command for setting MPP mode or not: 'MPP' then 0 or 1
SEL_MPP	MOVE	X:(R4)+,A
	JCLR	#0,A,NOT_MPP

YES_MPP	BSET	#MPP,X:STATUS		; MPP (AIMO) mode
	MOVE	#IS_PARALLEL,X0
	MOVE	X0,Y:PARALLEL_CLOCK
	JMP	<FINISH

NOT_MPP	BCLR	#MPP,X:STATUS		; Non-MPP mode
	MOVE	#IS_PARALLEL,X0
	MOVE	X0,Y:PARALLEL_CLOCK
	JMP	<FINISH

; Calculate the fast read parameters for each readout box
SETUP_SUBROUTINE
	MOVE	#(END_SERIAL_READ_LEFT-SERIAL_READ_LEFT),X0 ; # of waveforms
	MOVE	Y:<NSERIALS_READ,X1	; Number of pixels to read
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NREAD		; Number of waveforms per line
	MOVE	Y:<NR_BIAS,A		; Number of pixels to read
	JCLR	#SPLIT_S,X:STATUS,*+3	; Split serials require / 2
	ASR	A
	MOVE	A,X1			; Number of waveforms per line
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NBIAS		; Number of waveforms per line
	MOVE	#(END_SERIAL_SKIP_LEFT-SERIAL_SKIP_LEFT),X0 ; # of waveforms
	MOVE	Y:<NS_CLR,X1		; Number of pixels to skip
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NSCLR		; Number of waveforms per line
	MOVE	Y:<NS_SKP1,X1		; Number of pixels to skip
	MOVE	Y:<NSBIN,Y1		; Adjust for binning
	MPY	Y1,X1,A
	ASR	A
	MOVE	A0,X1
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NSKIP1		; Number of waveforms per line
	MOVE	Y:<NS_SKP2,X1		; Number of pixels to skip
	MOVE	Y:<NSBIN,Y1		; Adjust for binning
	MPY	Y1,X1,A
	ASR	A
	MOVE	A0,X1
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NSKIP2		; Number of waveforms per line
	MOVE	Y:<NP_SKIP,X1
	MOVE	Y:<NPBIN,Y1
	MPY	X1,Y1,A
	ASR	A
	MOVE	A0,Y:<NP_SKIP
	RTS

; Start exposure routine especially for frame transfer devices
START_FT_EXPOSURE
	JSR	<CLR_CCD		; Clear out the CCD
	MOVEP	X:TIM,Y:WRFO		; Transmit header word
	REP	#40			; Delay for transmission
	NOP
	MOVEP	X:DON,Y:WRFO		; 'DON'
	MOVE	#L_SEX,R7
	JMP	<EXPOSE			; Delay for specified exposure time
L_SEX
	JMP	<RDCCD			; Finally, read out the CCD