; This file is used to generate DSP code for the TimII second generation 
;     timing board. This is Rev. 3.00 software.   

; Code for Marconi's EEV42-80 2k x 4k thinned CCD sensor

	PAGE    132     ; Printronix page width - 132 columns

; Define a section name so it doesn't conflict with other application programs
	SECTION	TIMEEV42

; Include a header file that defines global parameters
	INCLUDE "/home/leach/DSPlib/timhdr.asm"

APL_NUM	EQU	0	; Application number from 0 to 3

CC	EQU	CCDVIDREV3B+TIMREV4+UTILREV3+SHUTTER_CC+TEMP_POLY+SUBARRAY+BINNING+SPLIT_SERIAL

; Include miscellaneous timing commands
        INCLUDE "timmisc.asm"				; Custom
        INCLUDE "/home/leach/DSPlib/timCCDmisc.asm"	; Generic 


;**************************************************************************
;                   	                                                  *
;    Permanent address register assignments                               *
;	 R1 - Address of SSI receiver contents				  *
;	 R2 - Address of SCI receiver contents				  *
;        R3 - Pointer to current top of command buffer                    *
;        R4 - Pointer to processed contents of command buffer		  *
;        R5 - Temporary register for processing SSI and SCI contents      *
;        R6 - CCD clock driver address for CCD #0 = $FF80                 *
;                It is also the A/D address of analog board #0            *
;                                                                         *
;    Other registers                                                      *
;        R0, R7 - Temporary registers used all over the place.            *
;        R5 - Can be used as a temporary register but is circular,        *
;               modulo 32.       					  *
;**************************************************************************

;  Specify execution and load addresses
	IF	@SCP("DOWNLOAD","HOST")
	ORG	P:APL_ADR,P:APL_ADR		; Download address
	ELSE
	ORG     P:APL_ADR,P:APL_NUM*N_W_APL	; EEPROM address
	ENDIF

; Keep the CCD idling when not reading out
IDLE	DO      Y:<NSR,IDL1     	; Loop over number of pixels per line
	MOVE    #<SERIAL_IDLE,R0 	; Serial transfer on pixel
	JSR     <CLOCK  		; Go to it
	JSR	<GET_RCV		; Check for FO or SSI commands
	JCC	<NO_COM			; Continue IDLE if no commands received
	ENDDO   			; Cancel the DO loop
	JMP     <CHK_SSI		; Go process header and command
NO_COM  NOP
IDL1
	MOVE    #<PARALLEL_CLEAR,R0	; Address of parallel clocking waveform
	JSR     <CLOCK  		; Go clock out the CCD charge
	JMP     <IDLE

;  ***********************   CCD  READOUT   ***********************

RDCCD	BSET	#ST_RDC,X:<STATUS 	; Set status to reading out
	BSET	#WW,X:PBD		; Set WW = 1 for 16-bit image data
	JSET	#TST_IMG,X:STATUS,SYNTHETIC_IMAGE

; Calculate some more readout parameters
	MOVE	Y:<NBOXES,A		; NBOXES = 0 => full image readout
	TST	A
	JNE	<SUB_IMG
	MOVE	A1,Y:<NS_SKP1		; Zero these all out
	MOVE	A1,Y:<NS_SKP2
	MOVE	Y:<NSR,A		; NSERIALS_READ = NSR
	JCLR	#SPLIT_S,X:STATUS,*+3
	ASR	A			; Split serials require / 2
	MOVE	A,Y:<NSERIALS_READ	; Number of columns in each subimage
	JMP	<SETUP

; Loop over the required number of subimage boxes
SUB_IMG	MOVE	#READ_TABLE,R7		; Parameter table for subimage readout
	DO	Y:<NBOXES,L_NBOXES	; Loop over number of boxes
	MOVE	Y:(R7)+,X0
	MOVE	X0,Y:<NP_SKIP
	MOVE	Y:(R7)+,X0
	MOVE	X0,Y:<NS_SKP1
	MOVE	Y:(R7)+,X0
	MOVE	X0,Y:<NS_SKP2
	MOVE	Y:<NS_READ,A
	JCLR	#SPLIT_S,X:STATUS,*+3	; Split serials require / 2
	ASR	A
	MOVE	A,Y:<NSERIALS_READ	; Number of columns in each subimage

; Calculate the fast read parameters
SETUP	MOVE	#(END_SERIAL_READ_L-SERIAL_READ_L),X0 ; # of waveforms
	MOVE	Y:<NSERIALS_READ,X1	; Number of pixels to read
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NREAD		; Number of waveforms per line
	MOVE	Y:<NR_BIAS,A		; Number of pixels to read
	JCLR	#SPLIT_S,X:STATUS,*+3	; Split serials require / 2
	ASR	A
	MOVE	A,X1			; Number of waveforms per line
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NBIAS		; Number of waveforms per line
	MOVE	#(END_SERIAL_SKIP_L-SERIAL_SKIP_L),X0 ; # of waveforms
	MOVE	Y:<NS_CLR,X1		; Number of pixels to skip
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NSCLR		; Number of waveforms per line
	MOVE	Y:<NS_SKP1,X1		; Number of pixels to skip
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NSKIP1		; Number of waveforms per line
	MOVE	Y:<NS_SKP2,X1		; Number of pixels to skip
	JSR	<FASTSKP		; Compute number of clocks required
	MOVE	X1,Y:<NSKIP2		; Number of waveforms per line

; Skip over the required number of rows for subimage readout
	MOVE	Y:<NP_SKIP,A		; Number of rows NPSKIP to skip
	TST	A
	JEQ	<CLR_SR
	DO      Y:<NP_SKIP,LPR_SKIP	; Clock number of rows to skip
	MOVE    #<PARALLEL_CLEAR,R0
	JSR     <CLOCK
	NOP
LPR_SKIP

; Clear out the accumulated charge from the serial shift register 
CLR_SR	MOVE	#(END_SERIAL_SKIP_L-SERIAL_SKIP_L-1),M1 ; Modularity
	MOVE	Y:<SERIAL_SKIP,R1	; Waveform table starting address
	NOP
	MOVE    Y:(R1)+,A       	; Start the pipeline
	DO	Y:<NSCLR,LS_CLR		; Number of waveform entries total
	MOVE    A,X:(R6) Y:(R1)+,A      ; Send out the waveform
LS_CLR
	MOVE    A,X:(R6)        	; Flush out the pipeline

; Parallel shift the image into the serial shift register
	MOVE	Y:<NPR,X0		; Number of rows set by host computer
	MOVE	Y:<NBOXES,A		; NBOXES = 0 => full image readout
	TST	A
	JEQ	*+2
	MOVE	Y:<NP_READ,X0		; If NBOXES .NE. 0 use subimage table

; Main loop over each line to be read out
	DO      X0,LPR			; Number of rows to read out

; Check for a command once per line. Only the ABORT command is allowed
	JSR	<GET_RCV		; Was a command received?
	JCC	<CONT_RD		; If no, continue reading out
	JMP	<CHK_SSI		; If yes, go process it

; Abort the readout currently underway
ABR_RDC JCLR	#ST_RDC,X:<STATUS,START	; Do nothing - we're not reading out
	ENDDO				; Properly terminate readout loop
	MOVE	Y:<NBOXES,A		; NBOXES = 0 => full image readout
	TST	A
	JEQ	*+2
	ENDDO				; Properly terminate readout loop
	JMP	<RDC_END

CONT_RD	DO      Y:<NPBIN,LPR_I  	; Transfer # of rows, with binning
	MOVE    #<PARALLEL,R0
	JSR     <CLOCK			; Parallel clocking
	NOP
LPR_I

; Skip over NS_SKP1 columns for subimage readout
	MOVE	Y:<NS_SKP1,A		; Number of columns to skip
	TST	A
	JEQ	<L_READ
	MOVE	#<(END_SERIAL_SKIP_L-SERIAL_SKIP_L-1),M1 ; Modularity
	MOVE	Y:<SERIAL_SKIP,R1	; Waveform table starting address
	NOP
	MOVE    Y:(R1)+,A       	; Start the pipeline
	DO	Y:<NSKIP1,LS_SKIP1	; Number of waveform entries total
	MOVE    A,X:(R6) Y:(R1)+,A      ; Send out the waveform
LS_SKIP1
	MOVE    A,X:(R6)        	; Flush out the pipeline

; Finally read some real pixels - this is the serial binning routine
L_READ	MOVE	Y:<NSBIN,B		; Serial binning parameter
	MOVE	X:<ONE,X0
	CMP	X0,B
	JEQ	<NO_BIN			; Skip over serial binning software

	DO      Y:<NSERIALS_READ,LSR_BIN ; Number of pixels to read out
	MOVE	#<CCD_RESET,R0		; Reset the output node(s)
	JSR	<CLOCK
	DO      Y:<NSBIN,LSR_I  	; Bin serially NSBIN times
	MOVE	Y:<SERIAL_CLOCK,R0 	; Clock the charge in the serial
	JSR     <CLOCK			;   shift register
	NOP
LSR_I
	MOVE	#VIDEO_PROCESS,R0 	; Video process the binned pixel
	JSR     <CLOCK
	NOP
LSR_BIN
	JMP	<OVER_RD		; All done binning

; This is the routine for NO serial binning 
NO_BIN	MOVE	#<(END_SERIAL_READ_L-SERIAL_READ_L-1),M1 ; Modularity
	MOVE	Y:<SERIAL_READ,R1	; Waveform table starting address
	NOP
	MOVE    Y:(R1)+,A       	; Start the pipeline
	DO	Y:<NREAD,LSR		; Number of waveform entries total
	MOVE    A,X:(R6) Y:(R1)+,A      ; Send out the waveform
LSR
	MOVE    A,X:(R6)        	; Flush out the pipeline

; Skip over NS_SKP1 columns for subimage readout
OVER_RD	MOVE	Y:<NS_SKP2,A		; Number of columns to skip
	TST	A
	JEQ	<L_BIAS
	MOVE	#<(END_SERIAL_SKIP_L-SERIAL_SKIP_L-1),M1 ; Modularity
	MOVE	Y:<SERIAL_SKIP,R1	; Waveform table starting address
	NOP
	MOVE    Y:(R1)+,A       	; Start the pipeline
	DO	Y:<NSKIP2,LS_SKIP2	; Number of waveform entries total
	MOVE    A,X:(R6) Y:(R1)+,A      ; Send out the waveform
LS_SKIP2
	MOVE    A,X:(R6)        	; Flush out the pipeline

; And read the bias pixels if in subimage readout mode
L_BIAS	MOVE	Y:<NBOXES,A		; NBOXES = 0 => full image readout
	TST	A
	JEQ	<END_ROW

; Finally read some real bias pixels
	MOVE	Y:<NSBIN,B		; Serial binning parameter
	MOVE	X:<ONE,X0
	CMP	X0,B
	JEQ	<NO_BIN_BIAS		; Skip over serial binning software

	MOVE	Y:<NR_BIAS,A
	JCLR	#SPLIT_S,X:STATUS,*+3
	ASR	A			; Split serials require / 2
	DO      A,LBIAS_BIN		; Number of pixels to read out
	MOVE	#<CCD_RESET,R0		; Reset the output node(s)
	JSR	<CLOCK
	DO      Y:<NSBIN,LBIAS_I  	; Bin serially NSBIN times
	MOVE	Y:<SERIAL_CLOCK,R0 	; Clock the charge in the serial
	JSR     <CLOCK			;   shift register
	NOP
LBIAS_I
	MOVE	#<VIDEO_PROCESS,R0 	; Video process the binned pixel
	JSR     <CLOCK
	NOP
LBIAS_BIN
	JMP	<END_ROW		; All done binning

; This is the NO serial binning routine
NO_BIN_BIAS
	MOVE	#<(END_SERIAL_READ_L-SERIAL_READ_L-1),M1 ; Modularity
	MOVE	Y:<SERIAL_READ,R1	; Waveform table starting address
	NOP
	MOVE    Y:(R1)+,A       	; Start the pipeline
	DO	Y:<NBIAS,LR_BIAS	; Number of waveform entries total
	MOVE    A,X:(R6) Y:(R1)+,A      ; Send out the waveform
LR_BIAS
	MOVE    A,X:(R6)        	; Flush out the pipeline
END_ROW	NOP
LPR	NOP				; End of parallel loop
L_NBOXES NOP				; End of subimage boxes loop

; Restore the controller to non-image data transfer and idling if necessary
RDC_END	BCLR	#WW,X:PBD		; Clear WW to 0 for 32-bit commands
	BCLR	#ST_RDC,X:<STATUS 	; Set status to reading out
	JCLR	#IDLMODE,X:<STATUS,START ; Don't idle after readout
	MOVE	#IDLE,X0
	MOVE	X0,X:<IDL_ADR
        JMP     <START			; Wait for a new command

; Core subroutine for clocking out CCD charge
CLOCK   MOVE    Y:(R0)+,X0      ; # of waveform entries 
        MOVE    Y:(R0)+,A       ; Start the pipeline
        DO      X0,CLK1                 ; Repeat X0 times
        MOVE    A,X:(R6) Y:(R0)+,A      ; Send out the waveform
CLK1
        MOVE    A,X:(R6)        ; Flush out the pipeline
        RTS                     ; Return from subroutine

; Check for program overflow
        IF	@CVS(N,*)>$200
        WARN    'Application P: program is too large!'	; Make sure program
	ENDIF						;  will not overflow

; ***********  DATA AREAS - READOUT PARAMETERS AND WAVEFORMS  ************

; Command table - make sure there are exactly 32 entries in it
	IF	@SCP("DOWNLOAD","HOST")
	ORG	X:COM_TBL,X:COM_TBL			; Download address
	ELSE			
        ORG     P:COM_TBL,P:APL_NUM*N_W_APL+APL_LEN+$200 ; EEPROM address
	ENDIF
	DC	'IDL',IDL  	; Put CCD in IDLE mode    
	DC	'STP',STP  	; Exit IDLE mode
	DC	'SBV',SETBIAS 	; Set DC bias supply voltages  
	DC	'RDC',RDCCD 	; Begin CCD readout    
	DC	'CLR',CLEAR  	; Fast clear the CCD   
	DC	'SGN',ST_GAIN  	; Set video processor gain     
	DC	'WRC',WR_CNTRL	; Write control word over SSI link
	DC	'SDC',SET_DC	; Set DC coupled diagnostic mode
	DC	'SBN',SET_BIAS_NUMBER	; Set bias number
	DC	'SMX',SET_MUX	; Set clock driver MUX output
	DC	'ABR',ABR_RDC	; Abort readout
	DC	'CRD',CONT_RD	; Continue reading out
	DC	'DON',START	; Nothing special
	DC	'CSW',CLR_SWS	; Clear analog switches to reduce power drain
	DC	'SOS',SEL_OS	; Select output source
	DC	'RCC',READ_CONTROLLER_CONFIGURATION 

	DC	'OSH',OPEN_SHUTTER
	DC	'CSH',CLOSE_SHUTTER
	DC      'PON',PWR_ON		; Turn on all camera biases and clocks
	DC      'POF',PWR_OFF		; Turn +/- 15V power supplies off

	DC	'SET',SET_EXP_TIME 	; Set exposure time
	DC	'RET',RD_EXP_TIME 	; Read elapsed exposure time
	DC	'SEX',START_EXPOSURE
	DC	'PEX',PAUSE_EXPOSURE
	DC	'REX',RESUME_EXPOSURE
	DC	'AEX',ABORT_EXPOSURE
	DC	0,START,0,START,0,START,0,START
	DC	0,START,0,START

	IF	@SCP("DOWNLOAD","HOST")
	ORG	Y:0,Y:0		; Download address
	ELSE
	ORG     Y:0,P:		; EEPROM address continues from P: above
	ENDIF
GAIN	DC	0		; Video processor gain and integrator speed
NSR     DC      560   	 	; Number Serial Read, prescan + image + bias
NPR     DC      512     	; Number Parallel Read
NS_CLR	DC      1120  		; To clear serial register
NPCLR   DC      4100    	; To clear parallel register, 2 images 
NSBIN   DC      1       	; Serial binning parameter
NPBIN   DC      1       	; Parallel binning parameter
TST_DAT	DC	0		; Temporary definition for test images
SH_DEL	DC	10		; Delay in milliseconds between shutter closing 
				;   and image readout
CONFIG	DC	CC		; Controller configuration

; Readout peculiarity parameters
SERIAL_SKIP 	DC	SERIAL_SKIP_L	; Address of serial skipping waveforms
SERIAL_READ	DC	SERIAL_READ_L	; Address of serial waveform table
SERIAL_CLOCK 	DC	SERIAL_CLOCK_L	; Address of serial clocking waveforms
OS		DC	'__L'		; The name of the Output Source(s)
NSERIALS_READ	DC	0		; Number of serials to read
NSCLR		DC	0		; Number of waveforms in fast mode
NSKIP1		DC	0		; Number of waveforms in fast mode
NREAD		DC	0		; Number of waveforms in fast mode
NSKIP2		DC	0		; Number of waveforms in fast mode
NBIAS		DC	0		; Number of waveforms in fast mode

; Subimage readout parameters. Ten subimage boxes maximum
NBOXES	DC	0		; Number of boxes to read
NR_BIAS	DC	200		; Number of bias pixels to read
NS_READ	DC	200		; Number of columns per box
NP_READ	DC	200		; Number of rows per box
READ_TABLE	DC	100,100,3000,50,200,3000,0,0,0,0	
		DC	0,0,0,0,0,0,0,0,0,0
		DC	0,0,0,0,0,0,0,0,0,0
NP_SKIP		DC	0	; Number of rows to skip
NS_SKP1		DC	0	; Number of serials to clear before read
NS_SKP2		DC	0	; Number of serials to clear after read

; Include the waveform table
	INCLUDE "EEV4280.waveforms" ; Readout and clocking waveforms

	IF	@SCP("DOWNLOAD","EEPROM")
		IF	@CVS(N,@LCV(L))>(APL_NUM+1)*N_W_APL
	WARN    'EEPROM overflow!'	; Make sure next application
		ENDIF			;   will not be overwritten
	ENDIF

	ENDSEC				; End of section TIMEEV42

;  End of program
	END